3500          BYT 0,100,55           ! 4 Numeric Params.
3510 DSRA20   BIN 
3520          POMD R60,-R12          ! Get Seek Address
3530          JSB =CONINT            ! Convert
3540          STM R76,R44            ! Save it in R44-5
3550          JSB =ONEB              ! Get ROM#
3560          STB R76,R75            ! Save it in R75
3570          POMD R60,-R12          ! Get Finish Address
3580          JSB =CONINT            ! Convert
3590          STM R76,R42            ! Save it in R42-3
3600          POMD R60,-R12          ! Get Start Address
3610          JSB =CONINT            ! Convert to Binary in R76-7
3620          LDM R46,R44            ! Move Seek Addr.
3630          LDM R66,R42            ! Move Finish addr.
3640          DCM R76                ! Get ready for start
3650 MOREA    ICM R76                ! Increment Start address
3660          STBD R75,=RSELEC       ! Select ROM
3670          LDMD R56,R76           ! Get 2 bytes from ROM
3680          CMM R56,R46            ! Have we found it?
3690          JZR O/P                ! JIF So
3700          CMM R66,R76            ! Carry on?
3710          JCY MOREA              ! JIF So
3720 O/P-     CLM R55                ! Nothing found
3725          DCM R55                ! Make it negative
3727          JMP O/P+    
3730 O/P      STM R76,R55            ! Want 3 bytes for Conversion
3740          CLB R57                ! Zro MSB
3750 O/P+     CLB R75
3760          STBD R75,=RSELEC       ! Finished with ROM#
3770          JSB =CONBI3            ! Change to floating point
3780          PUMD R40,+R12          ! Push onto stack
3790          RTN                    ! Done
3900 !*************************************************************************
4000          BYT 0,100,55           ! 4 Numeric Params.
4010 DSRB21   BIN 
4020          JSB =ONEB              ! Get Seek Byte
4030          STB R76,R45            ! Save it in R45
4040          JSB =ONEB              ! Get ROM#
4050          STB R76,R75            ! Save it in R75
4060          POMD R60,-R12          ! Get Finish Address
4070          JSB =CONINT            ! Convert
4080          STM R76,R42            ! Save it in R42-3
4090          POMD R60,-R12          ! Get Start Address
4100          JSB =CONINT            ! Convert to Binary in R76-7
4110          LDB R47,R45            ! Move Seek Byte.
4120          LDM R66,R42            ! Move Finish addr.
4130          DCM R76                ! Get ready for start
4140 MOREB    ICM R76                ! Increment Start address
4150          STBD R75,=RSELEC       ! Select ROM
4160          LDBD R57,R76           ! Get 1 byte from ROM
4170          CMB R57,R47            ! Have we found it?
4180          JZR O/P                ! JIF So
4190          CMM R66,R76            ! Carry on?
4200          JCY MOREB              ! JIF So
4205          JMP O/P-               ! Nothing found
4900 !*************************************************************************
5000          FIN